Euphoria Audio, LLC

An application I wrote to automatically collect log files from dozens of different Windows web servers required authentication in order to get to the log files. Leaving the folders wide open for "Everyone" would have been a terrible idea, naturally, as visitor IPs, usernames and other sensitive information could be gathered and used for nefarious purposes. FTP could have been used but not all of the servers had the service installed and management would be a bit of a pain. And sincere there weren't any firewall rules blocking CIFS access to the servers, we could just setup a share and easily grab logs.

First I looked at user impersonation, something the ASP.Net web developers at the government agency used often for accessing shares using domain authentication. However impersonation only works for domain accounts or accounts that reside on the local machine and as I didn't want to go through the trouble of getting an AD user just for log access, I had to find another way.

A long search brought me to the netapi32.dll which handles Net Use command lines for mapping drives, devices and other neat things usually seen in login scripts and such. I found almost exactly what I needed in a post by Willy Denoyette on an unofficial Microsoft usergroup but the code was in C# (which I prefer myself) but the agency standards only allow for VB code. I couldn't find the VB version anywhere and there were a few requests, so here's a class, with descriptions, that you can plug into your project and authenticate to any share.

First off, you have to import the Interop class to allow .Net to work with unmanaged code.

Imports System.Runtime.InteropServices

Next we have to declare a structure similar to the USE_INFO_2 structure used by the unmanaged .dll.

''' <summary>
''' VB.NET version of the USE_INFO_2 class needed to access
''' remote file shares by the NetApi32.dll file
''' </summary>
<StructLayout(LayoutKind.Sequential)> Public Structure USE_INFO_2
    <MarshalAs(UnmanagedType.LPWStr)> Dim ui2_local As String
    <MarshalAs(UnmanagedType.LPWStr)> Dim ui2_remote As String
    <MarshalAs(UnmanagedType.LPWStr)> Dim ui2_password As String
    Dim ui2_status As UInt32
    Dim ui2_asg_type As UInt32
    Dim ui2_refcount As UInt32
    Dim ui2_usecount As UInt32
    <MarshalAs(UnmanagedType.LPWStr)> Dim ui2_username As String
    <MarshalAs(UnmanagedType.LPWStr)> Dim ui2_domainname As String
End Structure

Note that the strings must be marshalled as LPWstr types in order to be parsed correctly by the dll. Next we have to define an enumerator to define how to close an existing network connection if it exists.

''' <summary>
''' Enumerator for handling the deletion of a shared resource
''' USE_NOFORCE - does not close the connection if open files exist
''' USE_FORCE - fails the disconnection even if open files exist
''' USE_LOGS_OF_FORCE - closes open files then deletes the connection
''' </summary>
Enum ForceCond
    USE_NOFORCE
    USE_FORCE
    USE_LOTS_OF_FORCE
End Enum

The next step is to use the DllImport method to create a reference to the dll's NetUseAdd method that will let us provide credentials and connect to another network share.

''' <summary>
''' Imports the NetUseAdd method from the NetAPI32 that tells windows to add access to a UNC share
''' with the provided credentials
''' </summary>
''' <param name="UncServerName">Share name, usually set this to Nothing</param>
''' <param name="Level">Should always be 2 to indicate we're authenticating to a shared resource. 1 means
''' we are not authenticated and would need a USE_INFO_1 structure</param>
''' <param name="Buf">The USE_INFO_2 structure to pass</param>
''' <param name="ParmError">A pointer to a value that receives the index of the first member of the
''' information structure in error when the ERROR_INVALID_PARAMETER error is returned.
''' If this parameter is NULL, the index is not returned on error.</param>
''' <returns>0 on login success, a system error code if there was an error</returns>
<DllImport("C:\windows\system32\netapi32.dll")> Public Shared Function NetUseAdd(ByRef UncServerName As String, ByVal Level As UInt32, ByRef Buf As USE_INFO_2, ByRef ParmError As UInt32) As UInt32
End Function