Euphoria Audio, LLC

I highly recommend that you import the NetUseDel function as well. If you try to connect to a share on a remote machine while you are connected to the same remote using another set of credentials, even if it's a different share, Windows won't let you and you'll receive an error. So the best thing to do before attempting a connection is to iterate through all of the connections on your machine (just open a command prompt and type "NET USE" and hit enter to see) and delete any existing connections to the remote machine. There are likely other methods in the dll that you can use for listing connections. Thus to import NetUseDel, use:

''' <summary>
''' Imports the NetUseDel method from the NetAPI32 that tells windows to disconnect a UNC share
''' </summary>
''' <param name="UncServerName">Share name, usually set this to Nothing</param>
''' <param name="UseName">The shared resource on the local computer that should be disconnected. Usually
''' the ui2_remote value from USE_INFO_2</param>
''' <param name="ForceCond">Level of closure to set, i.e. don't close if files are open, etc</param>
''' <returns>o if successful, a system error code if there was an error</returns>
<DllImport("C:\windows\system32\netapi32.dll")> Public Shared Function NetUseDel(ByRef UncServerName As String, ByVal UseName As String, ByVal ForceCond As ForceCond) As UInt32
End Function

And finally, here is a little function that you can use to simplify connections to share. Note that it does not perform any drive mapping, just creates a connection using the provided credentials and then you will have to navigate to a the UNC using some other means.

''' <summary>
''' Attempts to connect to a remote share using the provided credentials. After authenticating, you
''' should be able to accesss the remote share. After you are finished with the share, call NetUseDel
''' </summary>
''' <param name="strUNCPath">UNC path to the share you want to access</param>
''' <param name="strUser">User name to logon with</param>
''' <param name="strDomain">Domain under which to logon. If local machine, use "localhost"</param>
''' <param name="strPass">Password to use</param>
''' <returns>True if the logon and access was successful, false if there was an error</returns>
Public Shared Function NetUseWithCredentials(ByVal strUNCPath As String, ByVal strUser As String, ByVal strDomain As String, ByVal strPass As String) As Boolean
    ' data check
    If (strUNCPath.Length < 2 Or strUser.Length < 2) Then
        Console.WriteLine("Remote_Logon." & (New System.Diagnostics.StackFrame()).GetMethod().Name & " Invalid path or user: " & strUNCPath & " | " & strUser)
        Return False
    End If

    Try
        ' delcar vars
        Dim useinfo As New USE_INFO_2()
        Dim paramErrorIndex As UInt32
        Dim returncode As UInt32

        ' store values in our structure
        useinfo.ui2_remote = strUNCPath
        useinfo.ui2_username = strUser
        useinfo.ui2_domainname = strDomain
        useinfo.ui2_password = strPass
        useinfo.ui2_asg_type = 0
        useinfo.ui2_usecount = 1

        ' try logging in
        returncode = NetUseAdd(Nothing, 2, useinfo, paramErrorIndex)

        ' check return code
        If (returncode = 0) Then
            Return True
        Else
            Console.WriteLine("Remote_Logon." & (New System.Diagnostics.StackFrame()).GetMethod().Name & " Unable to logon: " & strUNCPath & " | " & strUser & " | " & returncode)
            Return False
        End If
    Catch ex As Exception
        Console.WriteLine("Remote_Logon." & (New System.Diagnostics.StackFrame()).GetMethod().Name & " " & ex.ToString())
        Return False
    End Try
End Function